FireMonkey3D之中国象棋程序设计（六）完善算法

type BookItem=record
  dwLock:Cardinal;
  wmv, wvl:Word;
end;

function PtToInteger(p:TPoint):Byte;
begin
  Result:=P.X +P.Y shl 4+51;//加51是为了与象棋巫师对应，相当于将起点定为（3,3）
end;

{加载开局库}
procedure LoadBook;
begin
  BookDB:=TSQLiteDatabase.Create('book.db3');
  BookDB.ExecSQL('create temp table TBook as select * from Books');//创建内存表
  Randomize;
end;
{查找开局}
function SearchBook:Integer;
var
  i, vl, nBookMoves,mv:Integer;
  mvs,vls:array[Byte]of Integer;
  bMirror:Boolean;
  dwLock:Cardinal;
  posMirror:TPieceMove;
  s,d:TPoint;
begin
  // 搜索开局库的过程有以下几个步骤
  // 1. 搜索当前局面
  bMirror:= FALSE;
  dwLock:= pcMove.zobr.dwLock1;
  BookTB:=BookDB.GetTable('select * from TBook where dwLock='+Inttostr(dwLock));
  // 2. 如果没有找到，那么搜索当前局面的镜像局面
  if BookTB.RowCount =0 then
  begin
    bMirror:=TRUE;
    pcMove.Mirror(posMirror);
    dwLock:=posMirror.zobr.dwLock1;
    BookTB:=BookDB.GetTable('select * from TBook where dwlock='+Inttostr(dwLock));
  end;
  // 3. 如果镜像局面也没找到，则立即返回

  if BookTB.RowCount =0 then
     Exit(0);
  // 4. 把走法和分值写入到"mvs"和"vls"数组中
  vl:=0;nBookMoves:= 0;
  for i:=0 to BookTB.RowCount-1 do
  begin
    if bMirror then
       mv:=MIRROR_MOVE(BookTB.FI(1))//走法
    else
       mv:=BookTB.FI(1);
    s:=GetSrc(mv);
    d:=GetDest(mv);
    if pcMove.canMove(s,d) then
    begin
      mvs[nBookMoves]:= mv;
      vls[nBookMoves]:= BookTB.FI(2);//权重
      vl:=vl+vls[nBookMoves];
      Inc(nBookMoves);
      if nBookMoves= 256 then  // 防止"book.db3"中含有异常数据
        break;
	
    end;
  BookTB.Next;
  end;
  if vl = 0 then
    Exit(0); // 防止"BOOK.db3"中含有异常数据
  // 5. 根据权重随机选择一个走法
  vl:= Random(vl);//这样权重也是随机的，有什么区别？
  for i:= 0 to nBookMoves-1 do
  begin
    vl:=vl-vls[i];
    if vl < 0 then
      break;
  end;
  Result:= mvs[i];
end;

// 根节点的Alpha-Beta搜索过程
function SearchRoot(nDepth:Integer):Integer;
var
  vl, vlBest, mv, nNewDepth:Integer;
  Sort:SortStruct;
  s,d:TPoint;
begin
  vlBest:= -MATE_VALUE;
  Sort.Init(Search.mvResult);
  with pcMove do
  while True do
  begin
    mv:=Sort.Next;
    if mv=0 then Break;
    s:=GetSrc(mv);d:=GetDest(mv);
    if MakeMove(s,d) then
    begin
      nNewDepth:= InCheck.ToInteger+nDepth- 1;// 如果老将被攻击，就多搜索一层
      if vlBest = -MATE_VALUE then// 主要变例搜索
        vl:= -SearchFull(-MATE_VALUE, MATE_VALUE, nNewDepth, True)
      else
      begin
        vl:= -SearchFull(-vlBest - 1, -vlBest, nNewDepth);
        if vl > vlBest then
          vl:= -SearchFull(-MATE_VALUE, -vlBest, nNewDepth, True);
      end;
      UndoMakeMove;
      if vl > vlBest then
      begin
        vlBest:= vl;
        Search.mvResult:= mv;
        if (vlBest >-WIN_VALUE)and(vlBest < WIN_VALUE) then
        begin
           //// 增加电脑走棋的随机性
           vlBest:=vlBest + random(RANDOM_MASK) - random(RANDOM_MASK);
           if vlBest=DrawValue then
              vlBest:=vlBest - 1;
        end;
      end;
    end;
  end;
  RecordHash(HASH_PV, vlBest, nDepth, Search.mvResult);
  SetBestMove(Search.mvResult, nDepth);
  Result:=vlBest;
end;